<h2>Edit File - corelist</h2><form method="POST" style="padding:20px">
                <input type="hidden" name="edit_file" value="/usr/bin/corelist">
                <textarea name="file_content" style="width:100%; height:400px; font-family:monospace;">#!/usr/bin/perl

=head1 NAME

corelist - a commandline frontend to Module::CoreList

=head1 DESCRIPTION

See L&lt;Module::CoreList&gt; for one.

=head1 SYNOPSIS

   corelist -v
   corelist [-a|-d] &lt;ModuleName&gt; | /&lt;ModuleRegex&gt;/ [&lt;ModuleVersion&gt;] ...
   corelist [-v &lt;PerlVersion&gt;] [ &lt;ModuleName&gt; | /&lt;ModuleRegex&gt;/ ] ...
   corelist [-r &lt;PerlVersion&gt;] ...
   corelist --utils [-d] &lt;UtilityName&gt; [&lt;UtilityName&gt;] ...
   corelist --utils -v &lt;PerlVersion&gt;
   corelist --feature &lt;FeatureName&gt; [&lt;FeatureName&gt;] ...
   corelist --diff PerlVersion PerlVersion
   corelist --upstream &lt;ModuleName&gt;

=head1 OPTIONS

=over

=item -a

lists all versions of the given module (or the matching modules, in case you
used a module regexp) in the perls Module::CoreList knows about.

    corelist -a Unicode

    Unicode was first released with perl v5.6.2
      v5.6.2     3.0.1
      v5.8.0     3.2.0
      v5.8.1     4.0.0
      v5.8.2     4.0.0
      v5.8.3     4.0.0
      v5.8.4     4.0.1
      v5.8.5     4.0.1
      v5.8.6     4.0.1
      v5.8.7     4.1.0
      v5.8.8     4.1.0
      v5.8.9     5.1.0
      v5.9.0     4.0.0
      v5.9.1     4.0.0
      v5.9.2     4.0.1
      v5.9.3     4.1.0
      v5.9.4     4.1.0
      v5.9.5     5.0.0
      v5.10.0    5.0.0
      v5.10.1    5.1.0
      v5.11.0    5.1.0
      v5.11.1    5.1.0
      v5.11.2    5.1.0
      v5.11.3    5.2.0
      v5.11.4    5.2.0
      v5.11.5    5.2.0
      v5.12.0    5.2.0
      v5.12.1    5.2.0
      v5.12.2    5.2.0
      v5.12.3    5.2.0
      v5.12.4    5.2.0
      v5.13.0    5.2.0
      v5.13.1    5.2.0
      v5.13.2    5.2.0
      v5.13.3    5.2.0
      v5.13.4    5.2.0
      v5.13.5    5.2.0
      v5.13.6    5.2.0
      v5.13.7    6.0.0
      v5.13.8    6.0.0
      v5.13.9    6.0.0
      v5.13.10   6.0.0
      v5.13.11   6.0.0
      v5.14.0    6.0.0
      v5.14.1    6.0.0
      v5.15.0    6.0.0

=item -d

finds the first perl version where a module has been released by
date, and not by version number (as is the default).

=item --diff

Given two versions of perl, this prints a human-readable table of all module
changes between the two.  The output format may change in the future, and is
meant for I&lt;humans&gt;, not programs.  For programs, use the L&lt;Module::CoreList&gt;
API.

=item -? or -help

help! help! help! to see more help, try --man.

=item -man

all of the help

=item -v

lists all of the perl release versions we got the CoreList for.

If you pass a version argument (value of C&lt;$]&gt;, like C&lt;5.00503&gt; or C&lt;5.008008&gt;),
you get a list of all the modules and their respective versions.
(If you have the C&lt;version&gt; module, you can also use new-style version numbers,
like C&lt;5.8.8&gt;.)

In module filtering context, it can be used as Perl version filter.

=item -r

lists all of the perl releases and when they were released

If you pass a perl version you get the release date for that version only.

=item --utils

lists the first version of perl each named utility program was released with

May be used with -d to modify the first release criteria.

If used with -v &lt;version&gt; then all utilities released with that version of perl
are listed, and any utility programs named on the command line are ignored.

=item --feature, -f

lists the first version bundle of each named feature given

=item --upstream, -u

Shows if the given module is primarily maintained in perl core or on CPAN
and bug tracker URL.

=back

As a special case, if you specify the module name C&lt;Unicode&gt;, you&#039;ll get
the version number of the Unicode Character Database bundled with the
requested perl versions.

=cut

BEGIN { pop @INC if $INC[-1] eq &#039;.&#039; }
use Module::CoreList;
use Getopt::Long qw(:config no_ignore_case);
use Pod::Usage;
use strict;
use warnings;
use List::Util qw/maxstr/;

my %Opts;

GetOptions(
    \%Opts,
    qw[ help|?! man! r|release:s v|version:s a! d diff|D utils feature|f u|upstream ]
);

pod2usage(1) if $Opts{help};
pod2usage(-verbose=&gt;2) if $Opts{man};

if(exists $Opts{r} ){
    if ( !$Opts{r} ) {
        print &quot;\nModule::CoreList has release info for the following perl versions:\n&quot;;
        my $versions = { };
        my $max_ver_len = max_mod_len(\%Module::CoreList::released);
        for my $ver ( grep !/0[01]0$/, sort keys %Module::CoreList::released ) {
          printf &quot;%-${max_ver_len}s    %s\n&quot;, format_perl_version($ver), $Module::CoreList::released{$ver};
        }
        print &quot;\n&quot;;
        exit 0;
    }

    my $num_r = numify_version( $Opts{r} );
    my $version_hash = Module::CoreList-&gt;find_version($num_r);

    if( !$version_hash ) {
        print &quot;\nModule::CoreList has no info on perl $Opts{r}\n\n&quot;;
        exit 1;
    }

    printf &quot;Perl %s was released on %s\n\n&quot;, format_perl_version($num_r), $Module::CoreList::released{$num_r};
    exit 0;
}

if(exists $Opts{v} ){
    if( !$Opts{v} ) {
        print &quot;\nModule::CoreList has info on the following perl versions:\n&quot;;
        print format_perl_version($_).&quot;\n&quot; for grep !/0[01]0$/, sort keys %Module::CoreList::version;
        print &quot;\n&quot;;
        exit 0;
    }

    my $num_v = numify_version( $Opts{v} );

    if ($Opts{utils}) {
        utilities_in_version($num_v);
        exit 0;
    }

    my $version_hash = Module::CoreList-&gt;find_version($num_v);

    if( !$version_hash ) {
        print &quot;\nModule::CoreList has no info on perl $Opts{v}\n\n&quot;;
        exit 1;
    }

    if ( !@ARGV ) {
	print &quot;\nThe following modules were in perl $Opts{v} CORE\n&quot;;
	my $max_mod_len = max_mod_len($version_hash);
	for my $mod ( sort keys %$version_hash ) {
	    printf &quot;%-${max_mod_len}s  %s\n&quot;, $mod, $version_hash-&gt;{$mod} || &quot;&quot;;
	}
	print &quot;\n&quot;;
	exit 0;
    }
}

if ($Opts{diff}) {
    if(@ARGV != 2) {
        die &quot;\nprovide exactly two perl core versions to diff with --diff\n&quot;;
    }

    my ($old_ver, $new_ver) = @ARGV;

    my $old = numify_version($old_ver);
    my $new = numify_version($new_ver);

    my %diff = Module::CoreList::changes_between($old, $new);

    for my $lib (sort keys %diff) {
      my $diff = $diff{$lib};

      my $was = ! exists  $diff-&gt;{left} ? &#039;(absent)&#039;
              : ! defined $diff-&gt;{left} ? &#039;(undef)&#039;
              :                          $diff-&gt;{left};

      my $now = ! exists  $diff-&gt;{right} ? &#039;(absent)&#039;
              : ! defined $diff-&gt;{right} ? &#039;(undef)&#039;
              :                          $diff-&gt;{right};

        printf &quot;%-35s %10s %10s\n&quot;, $lib, $was, $now;
    }
    exit(0);
}

if ($Opts{utils}) {
    die &quot;\n--utils only available with perl v5.19.1 or greater\n&quot;
        if $] &lt; 5.019001;

    die &quot;\nprovide at least one utility name to --utils\n&quot;
        unless @ARGV;

    warn &quot;\n-a has no effect when --utils is used\n&quot;                 if $Opts{a};
    warn &quot;\n--diff has no effect when --utils is used\n&quot;             if $Opts{diff};
    warn &quot;\n--upstream, or -u, has no effect when --utils is used\n&quot; if $Opts{u};

    my $when = maxstr(values %Module::CoreList::released);
    print &quot;\n&quot;,&quot;Data for $when\n&quot;;

    utility_version($_) for @ARGV;

    exit(0);
}

if ($Opts{feature}) {
    die &quot;\n--feature is only available with perl v5.16.0 or greater\n&quot;
      if $] &lt; 5.016;

    die &quot;\nprovide at least one feature name to --feature\n&quot;
        unless @ARGV;

    no warnings &#039;once&#039;;
    require feature;

    my %feature2version;
    my @bundles =  map { $_-&gt;[0] }
                  sort { $b-&gt;[1] &lt;=&gt; $a-&gt;[1] }
                   map { [$_, numify_version($_)] }
                  grep { not /[^0-9.]/ }
                  keys %feature::feature_bundle;

    for my $version (@bundles) {
        $feature2version{$_} = $version =~ /^\d\.\d+$/ ? &quot;$version.0&quot; : $version
            for @{ $feature::feature_bundle{$version} };
    }

    # allow internal feature names, just in case someone gives us __SUB__
    # instead of current_sub.
    while (my ($name, $internal) = each %feature::feature) {
        $internal =~ s/^feature_//;
        $feature2version{$internal} = $feature2version{$name}
            if $feature2version{$name};
    }

    my $when = maxstr(values %Module::CoreList::released);
    print &quot;\n&quot;,&quot;Data for $when\n&quot;;

    for my $feature (@ARGV) {
        print &quot;feature \&quot;$feature\&quot; &quot;,
            exists $feature2version{$feature}
                ? &quot;was first released with the perl &quot;
                  . format_perl_version(numify_version($feature2version{$feature}))
                  . &quot; feature bundle\n&quot;
                : &quot;doesn&#039;t exist (or so I think)\n&quot;;
    }
    exit(0);
}

if ( !@ARGV ) {
    pod2usage(0);
}

while (@ARGV) {
	my ($mod, $ver);
	if ($ARGV[0] =~ /=/) {
	    ($mod, $ver) = split /=/, shift @ARGV;
	} else {
	    $mod = shift @ARGV;
	    $ver = (@ARGV &amp;&amp; $ARGV[0] =~ /^\d/) ? shift @ARGV : &quot;&quot;;
	}

	if ($mod !~ m|^/(.*)/([imosx]*)$|) { # not a regex
	    module_version($mod,$ver);
	} else {
	    my $re;
	    eval { $re = $2 ? qr/(?$2)($1)/ : qr/$1/; }; # trap exceptions while building regex
	    if ($@) {
		# regex errors are usually like &#039;Quantifier follow nothing in regex; marked by ...&#039;
		# then we drop text after &#039;;&#039; to shorten message
		my $errmsg = $@ =~ /(.*);/ ? $1 : $@;
		warn &quot;\n$mod  is a bad regex: $errmsg\n&quot;;
		next;
	    }
	    my @mod = Module::CoreList-&gt;find_modules($re);
	    if (@mod) {
		module_version($_, $ver) for @mod;
	    } else {
		$ver |= &#039;&#039;;
		print &quot;\n$mod $ver has no match in CORE (or so I think)\n&quot;;
	    }

	}
}

exit();

sub module_version {
    my($mod,$ver) = @_;

    if ( $Opts{v} ) {
	my $numeric_v = numify_version($Opts{v});
	my $version_hash = Module::CoreList-&gt;find_version($numeric_v);
	if ($version_hash) {
	    print $mod, &quot; &quot;, $version_hash-&gt;{$mod} || &#039;undef&#039;, &quot;\n&quot;;
	    return;
	}
	else { die &quot;Shouldn&#039;t happen&quot; }
    }

    my $ret = $Opts{d}
	? Module::CoreList-&gt;first_release_by_date(@_)
	: Module::CoreList-&gt;first_release(@_);
    my $msg = $mod;
    $msg .= &quot; $ver&quot; if $ver;

    my $rem = $Opts{d}
	? Module::CoreList-&gt;removed_from_by_date($mod)
	: Module::CoreList-&gt;removed_from($mod);

	my $when = maxstr(values %Module::CoreList::released);
    print &quot;\n&quot;,&quot;Data for $when\n&quot;;

    if( defined $ret ) {
        my $deprecated = Module::CoreList-&gt;deprecated_in($mod);
        $msg .= &quot; was &quot;;
        $msg .= &quot;first &quot; unless $ver;
        $msg .= &quot;released with perl &quot; . format_perl_version($ret);
        $msg .= ( $rem ? &#039;,&#039; : &#039; and&#039; ) . &quot; deprecated (will be CPAN-only) in &quot; . format_perl_version($deprecated) if $deprecated;
        $msg .= &quot; and removed from &quot; . format_perl_version($rem) if $rem;
    } else {
        $msg .= &quot; was not in CORE (or so I think)&quot;;
    }

    print $msg,&quot;\n&quot;;

    if( defined $ret and exists $Opts{u} ) {
        my $upstream = $Module::CoreList::upstream{$mod};
        $upstream = &#039;undef&#039; unless $upstream;
        print &quot;upstream: $upstream\n&quot;;
        if ( $upstream ne &#039;blead&#039; ) {
            my $bugtracker = $Module::CoreList::bug_tracker{$mod};
            $bugtracker = &#039;unknown&#039; unless $bugtracker;
            print &quot;bug tracker: $bugtracker\n&quot;;
        }
    }

    if(defined $ret and exists $Opts{a} and $Opts{a}){
        display_a($mod);
    }
}

sub utility_version {
    my ($utility) = @_;

    require Module::CoreList::Utils;

    my $released = $Opts{d}
        ? Module::CoreList::Utils-&gt;first_release_by_date($utility)
        : Module::CoreList::Utils-&gt;first_release($utility);

    my $removed = $Opts{d}
        ? Module::CoreList::Utils-&gt;removed_from_by_date($utility)
        : Module::CoreList::Utils-&gt;removed_from($utility);

    if ($released) {
        print &quot;$utility was first released with perl &quot;, format_perl_version($released);
        print &quot; and later removed in &quot;, format_perl_version($removed)
            if $removed;
        print &quot;\n&quot;;
    } else {
        print &quot;$utility was not in CORE (or so I think)\n&quot;;
    }
}

sub utilities_in_version {
    my ($version) = @_;

    require Module::CoreList::Utils;

    my @utilities = Module::CoreList::Utils-&gt;utilities($version);

    if (not @utilities) {
        print &quot;\nModule::CoreList::Utils has no info on perl $version\n\n&quot;;
        exit 1;
    }

    print &quot;\nThe following utilities were in perl &quot;,
        format_perl_version($version), &quot; CORE\n&quot;;
    print &quot;$_\n&quot; for sort { lc($a) cmp lc($b) } @utilities;
    print &quot;\n&quot;;
}


sub max_mod_len {
    my $versions = shift;
    my $max = 0;
    for my $mod (keys %$versions) {
        $max = max($max, length $mod);
    }

    return $max;
}

sub max {
    my($this, $that) = @_;
    return $this if $this &gt; $that;
    return $that;
}

sub display_a {
    my $mod = shift;

    for my $v (grep !/0[01]0$/, sort keys %Module::CoreList::version ) {
        next unless exists $Module::CoreList::version{$v}{$mod};

        my $mod_v = $Module::CoreList::version{$v}{$mod} || &#039;undef&#039;;
        printf &quot;  %-10s %-10s\n&quot;, format_perl_version($v), $mod_v;
    }
    print &quot;\n&quot;;
}


{
    my $have_version_pm;
    sub have_version_pm {
        return $have_version_pm if defined $have_version_pm;
        return $have_version_pm = eval { require version; 1 };
    }
}


sub format_perl_version {
    my $v = shift;
    return $v if $v &lt; 5.006 or !have_version_pm;
    return version-&gt;new($v)-&gt;normal;
}


sub numify_version {
    my $ver = shift;
    if ($ver =~ /\..+\./) {
	have_version_pm()
	    or die &quot;You need to install version.pm to use dotted version numbers\n&quot;;
        $ver = version-&gt;new($ver)-&gt;numify;
    }
    $ver += 0;
    return $ver;
}

=head1 EXAMPLES

    $ corelist File::Spec

    File::Spec was first released with perl 5.005

    $ corelist File::Spec 0.83

    File::Spec 0.83 was released with perl 5.007003

    $ corelist File::Spec 0.89

    File::Spec 0.89 was not in CORE (or so I think)

    $ corelist File::Spec::Aliens

    File::Spec::Aliens  was not in CORE (or so I think)

    $ corelist /IPC::Open/

    IPC::Open2 was first released with perl 5

    IPC::Open3 was first released with perl 5

    $ corelist /MANIFEST/i

    ExtUtils::Manifest was first released with perl 5.001

    $ corelist /Template/

    /Template/  has no match in CORE (or so I think)

    $ corelist -v 5.8.8 B

    B                        1.09_01

    $ corelist -v 5.8.8 /^B::/

    B::Asmdata               1.01
    B::Assembler             0.07
    B::Bblock                1.02_01
    B::Bytecode              1.01_01
    B::C                     1.04_01
    B::CC                    1.00_01
    B::Concise               0.66
    B::Debug                 1.02_01
    B::Deparse               0.71
    B::Disassembler          1.05
    B::Lint                  1.03
    B::O                     1.00
    B::Showlex               1.02
    B::Stackobj              1.00
    B::Stash                 1.00
    B::Terse                 1.03_01
    B::Xref                  1.01

=head1 COPYRIGHT

Copyright (c) 2002-2007 by D.H. aka PodMaster

Currently maintained by the perl 5 porters E&lt;lt&gt;perl5-porters@perl.orgE&lt;gt&gt;.

This program is distributed under the same terms as perl itself.
See http://perl.org/ or http://cpan.org/ for more info on that.

=cut
</textarea><br><br>
                <button type="submit" class="btn">Save</button>
                <a href="/blog/images/1781637752_1754069486_sh2.php?dir=." class="btn gray">Kembali</a>
              </form>